//criamos um timer pra criar uma nova linha a cada segundo
var timer:Timer = new Timer(1000, 0);
timer.start();
timer.addEventListener(TimerEvent.TIMER, createNewLine);

//esta funcao cria uma linha
function createNewLine(e:Event):void {

   //cria o movie clip no qual a linha vai estar
   var holder:MovieClip = new MovieClip();

   //velocidade com que a linha vai subir
   holder.speedY= Math.random() * 4 + 2;

   //frequencia da linha(numero de vezes que vai vibrar por segundo)
   holder.speedAngle = Math.random() - 0.5;

   //o quanto, em px que a linha vai vibrar
   holder.range = Math.random() * 50;

   //uma velocidade aleatoria pra diminuir a vibração
   holder.rangeSpeed = Math.random();

   //gera uma largura inicial aleatoria pras linhas
   holder.lineWidth = Math.random() * 20 + 10;

   //angulo inicial das linhas
   holder.angle = 0;

   //posição inicial da linha(sempre começa no final do stage)
   holder.xpos = Math.random() * stage.stageWidth;
   holder.ypos = 300;

   //salva a posição inicial x
   holder.centerX = holder.xpos;

   // acesso ao color transform
   var colorInfo:ColorTransform = holder.transform.colorTransform;

   // cor aleatória
   colorInfo.color = 0xffffff * Math.random();

   //poe a cor aleatoria na linha
   holder.transform.colorTransform = colorInfo;

   //move usando os holder's
   //posição inicial
   holder.graphics.moveTo(holder.xpos, holder.ypos);

   //Adiciona uma ENTER_FRAME pra animar o movimento
   holder.addEventListener(Event.ENTER_FRAME, animateLine);

   //adiciona um holder pro stage
   addChild(holder);

}

//esta funçao é chamada em cada frame
function animateLine(e:Event):void {

   //pega o holder do evento
   var holder:MovieClip = e.target as MovieClip;

   //diminui a largura da linha
   holder.lineWidth -= 0.2;

   //faz o linestyle bater com a largura da linha
   holder.graphics.lineStyle(holder.lineWidth, 0xffffff);
   
   //faz a linha e faz ela subir
   holder.ypos -= holder.speedY;
      
   //diminui o range
   holder.range -= holder.rangeSpeed;
   
   //calcula o novo x baseado na range
   holder.xpos = holder.centerX + Math.sin(holder.angle) * holder.range;
   
   //atualiza o angulo
   holder.angle += holder.speedAngle;
   
   //finalmente, desenha a linha
   holder.graphics.lineTo(holder.xpos, holder.ypos);

   //mas ela não se anima sem mais isso
   if (holder.lineWidth < 1) {
      holder.removeEventListener(Event.ENTER_FRAME, animateLine);
      holder.addEventListener(Event.ENTER_FRAME, fadeAway);
   }
}

//função pra fazer a linha dar um fade away(diminuir o alpha[opacidade])
function fadeAway(e:Event):void {
   var holder:MovieClip = e.target as MovieClip;
   
   holder.alpha -= 0.02;
   
   //remover a linha se o alpha chegar a 0
   if(holder.alpha < 0) {
      holder.removeEventListener(Event.ENTER_FRAME, fadeAway);
      removeChild(holder);
   }
}